martedì , Settembre 17 2019
Ultime Notizie
Home / Wireless & Networking / Mikrotik / Mikrotik VLAN e Switch

Mikrotik VLAN e Switch

Ciao Ragazzi,

ritorno a scrivere dopo qualche tempo per parlarvi della “nuova” gestione delle VLAN da parte dei device Mikrotik dalla versione 6.41 a salire.

Per chi come me è abituato al concetto di VLAN in stile Cisco, affrontare lo stesso discorso su Mikrotik può diventare problematico come già ho affrontato in questo articolo

Esistono diversi modi per configurare le VLAN su Mikrotik e ognuno di questi ha pro e contro. Vediamoli in dettaglio utilizzando sempre lo stesso scenario:

scenario di esempio

MODO 1: Configurazione “Classica”

In questa versione che io definisco “classica” le VLAN vengono definite sulla interfaccia ether1 e poi si crea un bridge dove aggiungo le aggiungo con le altre porte:

/interface vlan
add interface=ether1 name=vlan30 vlan-id=30
add interface=ether1 name=vlan20 vlan-id=20
add interface=ether1 name=vlan99 vlan-id=99
/interface bridge
add name=bridge30
add name=bridge20
/interface bridge port
add port=ether2 interface=bridge20
add port=vlan20 interface=bridge20
add port=ether3 interface=bridge30
add port=vlan30 interface=bridge30

In questo modo aggiungiamo le porte che ci servono in bridge con le vlan per mettere quelle porte in “access” su quella desiderata.

PRO: facilità di configurazione

CONTRO: Viene utilizzato il processore principale della routerboard. Man mano che aumenta il traffico sale l’utilizzo della CPU (es. in questa configurazione un CRS con porte 10G, con “soli” 500MB di traffico costante porta il processore al 100% quasi subito)

MODO 2: Configurazione “Nuova”

Nelle nuove routerboard (ormai in quasi tutte quelle di nuova generazione è presente) c’è un chip dedicato solo allo switching proprio per evitare di “appesantire” la CPU. Per le versioni Mikrotik 6.41.x potete fare riferimento alla mia precedente guida mentre per le versioni successive vediamo come gestire la cosa.

CRS3xx Serie

/interface bridge
add name=bridge1
/interface bridge port
add bridge=bridge1 interface=ether1 hw=yes
add bridge=bridge1 interface=ether2 hw=yes pvid=20
add bridge=bridge1 interface=ether3 hw=yes pvid=30
/interface bridge vlan
add bridge=bridge1 tagged=ether1 untagged=ether2 vlan-ids=20
add bridge=bridge1 tagged=ether1 untagged=ether3 vlan-ids=30
/interface bridge
set bridge1 vlan-filtering=yes

CRS1xx/CRS2xx Serie

/interface bridge
add name=bridge1
/interface bridge port
add bridge=bridge1 interface=ether1 hw=yes
add bridge=bridge1 interface=ether2 hw=yes
add bridge=bridge1 interface=ether3 hw=yes
/interface ethernet switch ingress-vlan-translation
add ports=ether2 customer-vid=0 new-customer-vid=20 sa-learning=yes
add ports=ether3 customer-vid=0 new-customer-vid=30 sa-learning=yes
/interface ethernet switch egress-vlan-tag
add tagged-ports=ether1 vlan-id=20
add tagged-ports=ether1 vlan-id=30
 
/interface ethernet switch vlan
add ports=ether1,ether2 vlan-id=20 learn=yes
add ports=ether1,ether3 vlan-id=30 learn=yes
add ports=ether1,switch1-cpu vlan-id=99 learn=yes
 
/interface ethernet switch
set drop-if-invalid-or-src-port-not-member-of-vlan-on-ports=ether1,ether2,ether3

Nell’esempio sopra indicato non ho necessità che le porte ether2 e ether3 siano in modalità ibrida(o trunk o access), ma sono semplicemente in access.

Se invece serve una modalità ibrida:

/interface bridge
add name=bridge1
/interface bridge port
add bridge=bridge1 interface=ether1 hw=yes
add bridge=bridge1 interface=ether2 hw=yes
add bridge=bridge1 interface=ether3 hw=yes
/interface bridge vlan
add bridge=bridge1 tagged=ether1,ether2,ether3 vlan-ids=20
add bridge=bridge1 tagged=ether1,ether2,ether3 vlan-ids=30
/interface bridge
set bridge1 vlan-filtering=yes

In questo modo le porte ether2 e ether3 verranno “comandate” da ciò che gli si collega e potranno dinamicamente far passare sia la vlan20 che la vlan30 a seconda del dispositivo che viene collegato.

PRO: Massimizzazione Throughput e utilizzo minimo della CPU principale

CONTRO: Complessità di configurazione specie nel caso di routerboard con numerose porte e con vlan diverse da gestire

Info Paolo Daniele

Ingegnere delle Telecomunicazioni, appassionato di informatica fin da piccolo ho trasformato la passione in lavoro. Con il PHP faccio tutto (o quasi...) ma non disprezzo altri linguaggi all'occorrenza. Se vi piace il mio sito, o vi è utile, o vi sto simpatico, offritemi una birra!

Ti potrebbe interessare

EZVPN: la rivoluzione nel campo delle VPN

Ciao Ragazzi, oggi vi parlo di un prodotto fantastico: EZVPN. Il prodotto all’apparenza sembra un …

Lascia un commento

Il tuo indirizzo email non sarà pubblicato. I campi obbligatori sono contrassegnati *